PREFIX schema: <http://schema.org/>

SELECT
  ?id
  ?date

  (GROUP_CONCAT(DISTINCT IF(LANG(?title)="fr", STR(?title), ""); separator=" ") AS ?title_fr)
  (GROUP_CONCAT(DISTINCT IF(LANG(?title)="de", STR(?title), ""); separator=" ") AS ?title_de)
  (GROUP_CONCAT(DISTINCT IF(LANG(?title)="it", STR(?title), ""); separator=" ") AS ?title_it)

  (GROUP_CONCAT(DISTINCT IF(LANG(?initiativtext)="fr", STR(?initiativtext), ""); separator=" ") AS ?text_fr)
  (GROUP_CONCAT(DISTINCT IF(LANG(?initiativtext)="de", STR(?initiativtext), ""); separator=" ") AS ?text_de)
  (GROUP_CONCAT(DISTINCT IF(LANG(?initiativtext)="it", STR(?initiativtext), ""); separator=" ") AS ?text_it)

WHERE {
  <https://politics.ld.admin.ch/political-rights/popular-initiative/1>
    <https://cube.link/observationSet> ?obsSet .

  ?obsSet <https://cube.link/observation> ?source .

  ?source
    <https://politics.ld.admin.ch/political-rights/popular-initiative/id> ?id ;
    <https://politics.ld.admin.ch/political-rights/popular-initiative/sammelbeginn> ?date ;
    <https://politics.ld.admin.ch/political-rights/popular-initiative/titel> ?titleUri ;
    <https://politics.ld.admin.ch/political-rights/popular-initiative/initiativtext> ?textUri .

  ?titleUri schema:name ?title .

  OPTIONAL { ?textUri schema:name ?initiativtext . }
}
GROUP BY ?id ?date
ORDER BY DESC(?date)
LIMIT 100